Suivre sa consommation d’eau : domotisation d’un compteur d’eau à l’aide d’un arduino

Bonne année à tous (mieux vaut tard que jamais :). Pour commencer cette année, un petit article sur le relevé automatique de la consommation d’eau. Le montage utilise un compteur d’eau banal du commerce (sans capteur donc) et ne nécessite pas son démontage.

[adsGrandRectangleTexte]

Relever sa consommation d’eau : les différentes solutions

Pour faire du relevé de compteurs d’eau, il n’y a pas 36 solutions. Il faut que le compteur soit équipé d’un capteur.

Les solutions commerciales, « plug&play », fiables … et pas trop bon marché

Il existe des compteurs avec une sortie pour un capteur à impulsion? J’en possède un de la marque Sappel, on peut lui ajouter un module nommé « Pulsar » mais outre le compteur qui coute ~40€ le module capteur coute lui ~80€ … 120€ pour avoir un retour de consommation d’eau, autant dire que c’est un investissement long terme … d’autant plus si l’on souhaite domotiser deux compteurs (eau froide et eau chaude).
Il en existe d’autres, le compteur d’eau ci-dessous avec sortie impulsion semble pas mal utilisé :

On le trouve chez planète domotique par exemple : http://www.planete-domotique.com/energie/consommation-d-eau/compteur-d-eau-froide-avec-sortie-impulsion-1-imp-1-litre.html. Coté prix c’est mieux mais on va faire mieux 🙂

La solution du pauvre, play&plug ;), aussi fiables et pas chères !

Comme d’habitude je suis parti sur une solution la moins chère possible et sans sacrifier la fiabilité.

Domotisons un compteur d’eau classique

Là aussi, il existe plusieurs solutions. Il y a des compteurs à roues, comme celui ci:

On peut les démonter et placer un petit aimant sur l’aiguille des litres puis placer un capteur, genre capteur d’ouverture de porte, dessus. A chaque tour, le capteur renvoie un changement de statut. Vous trouverez des infos sur ce type de montage ici : http://www.macoda.com/index.php/Montage:Compteur_eau_DS2423

Je ne voulais pas démonter mon compteur et j’ai opté pour une autre solution : la lumière.

Montage à base d’arduino et d’interrupteur optique

J’ai domotiser deux compteurs, celui de marque Sappel ainsi qu’un deuxième pour l’eau chaude de marque itron que l’on trouve à 20€ en GSB. J’ai choisi ces deux compteurs d’eau car il ont en commun de posséder un demi disque réfléchissant couleur métal (cf flèche rouge) qui fait un tour à chaque litre consommé :

L’idée est donc de trouver un capteur capable de détecter ce disque. J’ai choisi un CNY70. C’est un capteur de réflexion aussi appelé “interrupteur optique”.
Pour l’histoire, les capteurs de réflexions sont très présent en robotique. On peut utiliser notamment le CNY70 pour réaliser un suiveur de ligne. Il va permettre de différencier deux surfaces ayant une réflexion différente (la ligne noire du circuit et le blanc de la piste autour). Dans notre cas le demi disque réfléchissant.

Vous pouvez vous en procurer dans tous les magasins en ligne d’électronique aux alentours de 1€ ou directement chez le fabricant sous forme de sample (gratuit :).

Fonctionnement du CNY70 :

Il possède un émetteur et un récepteur infrarouge accordés sur la même longueur d’onde.
L’émetteur est une diode infrarouge et le récepteur est un phototransistor. La diode émet de la lumière IR en direction du disque. Si le capteur se trouve au dessus d’un objet de couleur claire, la lumière se reflète et vient frapper le phototransistor qui devient passant. Si on le connecte sur une pin digital de l’arduino, celle-ci passe à 1 lorsque quelque chose est détecté, sinon 0.

Pour connecter le capteur à l’arduino j’ai utilisé le schéma suivant (attention à la polarité, j’ai grillé bêtement la diode infrarouge sur un cny70) :

Les tests

L’arduino est maintenant capable de recevoir les informations du capteur CNY70.

Lors de mes premiers tests, le capteur était collé directement contre le compteur et il renvoyait toujours 1 (la lumière était réfléchie que le disque soit en face ou pas).
Il est donc préférable d’éloigner le capteur de quelque cm pour qu’il soit moins sensible. Pour ce faire, je l’ai enfermer dans un petit tube PVC (type gaine d’électricité rigide) d’un diamètre équivalent à celui du demi disque. J’ai ensuite coller ce dernier sur le compteur, en face du demi disque, avec un adhésif bien costaud (le résultat fait un peu bidouille peu être, l’idée c’est qu’il tienne bien et je suis sûr que certains feront bien mieux :).

Après quelques tests on trouve la distance adéquate (1 à 2cm) pour que la lumière soit réfléchie par le disque et pas par le fond.

Pour effectuer ces tests et trouver la bonne position du capteur, voici un stetch tout simple qui permet d’allumer la LED de la pin 13 de l’arduino lorsque le CNY70 détecte un objet :

#define LED 13
#define IN 3

volatile uint8_t state = LOW;

void cny70_onRising(void) 
{
    // bascule l'état de la led
    state = !state;

    Serial.print(state);
    Serial.println(" detected");
}

void setup () 
{
    Serial.begin(9600);
    Serial.println("CNY70 test");

    pinMode(IN, INPUT);
    pinMode(LED, OUTPUT);

    // Attache une interruption sur changement de valeur (pin 3)
    attachInterrupt(1, cny70_onRising, CHANGE);
}

void loop () 
{
  digitalWrite(LED, state);
}

Une fois la bonne configuration trouvée, vous pouvez fixer le CNY70 sur le compteur et vous aurez un retour à chaque ½ litre consommé (½ litre à chaque changement de valeur).

Ajoutons un peu d’xPL sur tout ça pour remonter les informations au serveur domotique

Il nous reste maintenant à propager l’information sur le réseau. Comme d’habitude, j’utilise le protocole xPL pour intégrer mon nouveau capteur à mon réseau domotique. Et je fais un peu de promo pour la librairie xPL.Arduino au passage 😉 voici le sketch final :

#include <xPL.h>
#include <EtherCard.h>

#define IN 3

volatile uint8_t state = LOW;

byte Ethernet::buffer[XPL_MESSAGE_BUFFER_MAX];
xPL xpl;

// Init du serveur HTTP
uint8_t mymac[6] = { 0x54,0x55,0x58,0x10,0x00,0x11 };
uint8_t myip[4] = { 192,168,1,136 };
uint8_t gwip[4] = { 192,168,1,1};

// Ethercard seems to only send broadcast on this addr
// if using xpl-perl, don't forget to add "--define broadcast=0.0.0.0" to the xpl-hub
uint8_t broadcast[4] = { 255,255,255,255};

void SendUdPMessage(char *buffer)
{
    ether.sendUdp (buffer, strlen(buffer), xpl.udp_port, broadcast, xpl.udp_port);
}

void cny70_onRising(void) 
{
    // bascule l'état de la led
    state = !state;

    // Un message xPL est remonté à chaque front montant (un litre)
    // On peut supprimer la condition pour envoyer un message tous les 1/2 litre
    if(state)
    {
      xPL_Message msg;

      msg.hop = 1;
      msg.type = XPL_TRIG;

      msg.SetTarget_P(PSTR("*"));
      msg.SetSchema_P(PSTR("sensor"), PSTR("basic"));

      msg.AddCommand_P(PSTR("device"),PSTR("Eau"));
      msg.AddCommand_P(PSTR("type"),PSTR("output"));
      msg.AddCommand_P(PSTR("current"),PSTR("HIGH"));

      xpl.SendMessage(&msg);
    }

    Serial.print(state);
    Serial.println(" detected");
}

void setup () 
{
    Serial.begin(9600);
    Serial.println("CNY70 test");

    // decommenter pour un mega et commenter la ligne en dessous
    // ether.begin(sizeof Ethernet::buffer, mymac);
    ether.begin(sizeof Ethernet::buffer, mymac, 10);

    ether.staticSetup(myip, gwip);

    xpl.SendExternal = &SendUdPMessage;  // pointer to the send callback
    xpl.SetSource_P(PSTR("xpl"), PSTR("arduino"), PSTR("CNY70Test")); // parameters for hearbeat message

    pinMode(IN, INPUT);

    // Attache une interruption sur changement de valeur (pin 3)
    attachInterrupt(1, cny70_onRising, CHANGE);
}

void loop () 
{
}

Précision / Fiabilité

Concernant la précision du système, Je l’ai utilisé sur un an et la précision était vraiment bonne. Sur les les 14000 premiers litres (env deux mois) j’ai eu un écart de 4 litres soit moins de 0.1% d’erreur.

Relever sa consommation d’eau chaude, l’astuce à 2 balle

Histoire de gagner 10€ et se dire qu’on est super malin …, pour la consommation d’eau chaude, plutôt que d’acheter un compteur pour eau chaude souvent plus cher, vous pouvez prendre un compteur d’eau froide et le placer à l’entrée du ballon d’eau chaude. Tout ce qui sort du ballon sera forcement entré en passant par le compteur, voila ça c’est fait 🙂

[adsGrandRectangleHTexte]

Conclusion

Le sketch est assez simple, il remonte sur le réseau en xPL chaque litre consommé, charge à vous d’en faire ce que vous voulez. Pour ma part, mon serveur log chaque litre en base, ensuite j’ai des scripts qui génère des graphs et agrège les données par heure/jour/mois pour limiter la taille en base.

On pourrait aussi ne pas envoyer un message à chaque litre mais stoker le total sur l’arduino et envoyer un rapport une fois pas jour par exemple ou à la demande. Pour plus de souplesse et facilité de maintenance, je préfère garder sur les arduino une logique très simple et centraliser l’intelligence.

Le prochain article parlera du relevé de la consommation électrique sur un vieux compteur à roue (et oui malheureusement ça existe encore) sans pince ampèremétrique mais basé sur ce même montage. Si vous voyez des améliorations ou d’autres montages possibles avec ce type de capteurs, n’hésitez pas à les partager!